aboutsummaryrefslogtreecommitdiff
path: root/amforth-6.5/avr8/words/reg-a.asm
blob: 196ca3ce2c7985fa0aafe426bcc3940866c9d1a7 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
; ( -- n2 ) 
; Extended VM
; Read memory pointed to by register A (Extended VM)
VE_AFETCH:
    .dw $ff02
    .db "a@"
    .dw VE_HEAD
    .set VE_HEAD = VE_AFETCH
XT_AFETCH:
    .dw PFA_AFETCH
PFA_AFETCH:
    savetos
    movw zl, al
    ld tosl, Z+
    ld tosh, Z+
    jmp_ DO_NEXT

; ( n1 -- n2 )
; Extended VM
; Read memory pointed to by register A plus offset (Extended VM)
VE_NAFETCH:
    .dw $ff03
    .db "na@",0
    .dw VE_HEAD
    .set VE_HEAD = VE_NAFETCH
XT_NAFETCH:
    .dw PFA_NAFETCH
PFA_NAFETCH:
    movw zl, al
    add zl, tosl
    adc zh, tosh
    ld tosl, Z+
    ld tosh, Z+
    jmp_ DO_NEXT

; ( -- n ) 
; Extended VM
; Read memory pointed to by register A, increment A by 1 cell (Extended VM)
VE_AFETCHPLUS:
    .dw $ff03
    .db "a@+",0
    .dw VE_HEAD
    .set VE_HEAD = VE_AFETCHPLUS
XT_AFETCHPLUS:
    .dw PFA_AFETCHPLUS
PFA_AFETCHPLUS:
    savetos
    movw zl, al
    ld tosl, Z+
    ld tosh, Z+
    movw al, zl
    jmp_ DO_NEXT

; ( -- n )
; Extended VM
; Read memory pointed to by register A, decrement A by 1 cell (Extended VM)
VE_AFETCHMINUS:
    .dw $ff03
    .db "a@-",0
    .dw VE_HEAD
    .set VE_HEAD = VE_AFETCHMINUS
XT_AFETCHMINUS:
    .dw PFA_AFETCHMINUS
PFA_AFETCHMINUS:
    savetos
    movw zl, al
    ld tosh, -Z  ; TODO: check byte order!! 
    ld tosl, -Z
    movw al, zl
    jmp_ DO_NEXT

; ( n -- )
; Extended VM
; Write memory pointed to by register A (Extended VM)
VE_ASTORE:
    .dw $ff02
    .db "a!"
    .dw VE_HEAD
    .set VE_HEAD = VE_ASTORE
XT_ASTORE:
    .dw PFA_ASTORE
PFA_ASTORE:
    movw zl, al
    st Z+, tosl
    st Z+, tosh
    loadtos
    jmp_ DO_NEXT

; ( n offs -- )
; Extended VM
; Write memory pointed to by register A plus offset (Extended VM)
VE_NASTORE:
    .dw $ff03
    .db "na!",0
    .dw VE_HEAD
    .set VE_HEAD = VE_NASTORE
XT_NASTORE:
    .dw PFA_NASTORE
PFA_NASTORE:
    movw zl, al
    add zl, tosl
    adc zh, tosh
    loadtos
    st Z+, tosl
    st Z+, tosh
    loadtos
    jmp_ DO_NEXT

; ( -- n2 )
; Extended VM
; Write memory pointed to by register A, increment A by 1 cell (Extended VM)
VE_ASTOREPLUS:
    .dw $ff03
    .db "a!+",0
    .dw VE_HEAD
    .set VE_HEAD = VE_ASTOREPLUS
XT_ASTOREPLUS:
    .dw PFA_ASTOREPLUS
PFA_ASTOREPLUS:
    movw zl, al
    st Z+, tosl
    st Z+, tosh
    loadtos
    movw al, zl
    jmp_ DO_NEXT

; ( -- n2 )
; Extended VM
; Write memory pointed to by register A, decrement A by 1 cell (Extended VM)
VE_ASTOREMINUS:
    .dw $ff03
    .db "a!-",0
    .dw VE_HEAD
    .set VE_HEAD = VE_ASTOREMINUS
XT_ASTOREMINUS:
    .dw PFA_ASTOREMINUS
PFA_ASTOREMINUS:
    movw zl, al
    st -Z, tosh
    st -Z, tosl
    loadtos
    movw al, zl
    jmp_ DO_NEXT



; ( n -- )
; Extended VM
; Write to A register (Extended VM)
VE_TO_A:
    .dw $ff02
    .db ">a"
    .dw VE_HEAD
    .set VE_HEAD = VE_TO_A
XT_TO_A:
    .dw PFA_TO_A
PFA_TO_A:
    movw al, tosl
    loadtos
    jmp_ DO_NEXT

; ( n1 -- n2 ) 
; Extended VM
; read the A register (Extended VM)
VE_A_FROM:
    .dw $ff02
    .db "a>"
    .dw VE_HEAD
    .set VE_HEAD = VE_A_FROM
XT_A_FROM:
    .dw PFA_A_FROM
PFA_A_FROM:
    savetos
    movw tosl, al
    jmp_ DO_NEXT

; for more information read
; http://www.complang.tuwien.ac.at/anton/euroforth/ef08/papers/pelc.pdf
;  adapted index based access from X/Y registers
;    note: offset is byte address, not cell!