aboutsummaryrefslogtreecommitdiff
path: root/docs/j1/toolchain/nuc.fs
blob: 846db05ce0751c7622ec6d9cf35aef1cb5aa758e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
header 1+       : 1+        d# 1 + ;
header 1-       : 1-        d# -1 + ;
header 0=       : 0=        d# 0 = ;
header cell+    : cell+     d# 2 + ;

header <>       : <>        = invert ; 
header >        : >         swap < ; 
header 0<       : 0<        d# 0 < ; 
header 0>       : 0>        d# 0 > ;
header 0<>      : 0<>       d# 0 <> ;
header u>       : u>        swap u< ; 

: eol   ( u -- u' false | true )
    d# -1 +
    dup 0= dup if
                        ( 0 true -- )
        nip
    then
;

header ms
: ms
    begin
        d# 15000 begin
        eol until
    eol until
;


header key?
: key?
    d# 0 io@
    d# 4 and
    0<>
;

header key
: key
    begin
        key?
    until
    d# 0 io@ d# 8 rshift
    d# 0 d# 2 io!
;

: ready
    d# 0 io@
    d# 2 and
    0=
;

header emit
: emit
    begin ready until
    h# 0 io!
;

header cr
: cr
    d# 13 emit
    d# 10 emit
;

header space
: space
    d# 32 emit
;

header bl
: bl
    d# 32
;

: hex1
    h# f and
    dup d# 10 < if
        [char] 0
    else
        d# 55
    then
    +
    emit
;

: hex2
    dup d# 4 rshift hex1 hex1
;

: hex4
    dup d# 8 rshift hex2 hex2
;

: hex8
    dup d# 16 rshift hex4 hex4
;

header .
: . hex8 space ;

header false    : false d# 0 ; 
header true     : true  d# -1 ; 
header rot      : rot   >r swap r> swap ; 
header -rot     : -rot  swap >r swap r> ; 
header tuck     : tuck  swap over ; 
header 2drop    : 2drop drop drop ; 
header ?dup     : ?dup  dup if dup then ;

header 2dup     : 2dup  over over ; 
header +!       : +!    tuck @ + swap ! ; 
header 2swap    : 2swap rot >r rot r> ;

header min      : min   2dup< if drop else nip then ;
header max      : max   2dup< if nip else drop then ;

header c@
: c@
    dup @ swap
    d# 3 and d# 3 lshift rshift
    d# 255 and
;

: hi16
    d# 16 rshift d# 16 lshift
;

: lo16
    d# 16 lshift d# 16 rshift
;

header uw@
: uw@
    dup @ swap
    d# 2 and d# 3 lshift rshift
    lo16
;

header w!
: w! ( u c-addr -- )
    dup>r d# 2 and if
        d# 16 lshift
        r@ @ lo16
    else
        lo16
        r@ @ hi16
    then
    or r> !
;

header c!
: c! ( u c-addr -- )
    dup>r d# 1 and if
        d# 8 lshift
        h# 00ff
    else
        h# 00ff and
        h# ff00
    then
    r@ uw@ and
    or r> w!
;

header count
: count
    dup 1+ swap c@
;

: bounds ( a n -- a+n a )
    over + swap
;

header type
: type
    bounds
    begin
        2dupxor
    while
        dup c@ emit
        1+
    repeat
    2drop
;

create base     $a ,
create ll       0 ,
create dp       0 ,
create tib#     0 ,
create >in      0 ,
create tib 80 allot

header words : words
    ll uw@
    begin
        dup
    while
        cr
        dup .
        dup cell+
        count type
        space
        uw@
    repeat
    drop
;

header dump : dump ( addr u -- )
    cr over hex4
    begin  ( addr u )
        ?dup
    while
        over c@ space hex2
        1- swap 1+   ( u' addr' )
        dup h# f and 0= if  ( next line? )
            cr dup hex4
        then
        swap
    repeat
    drop cr
;

header negate   : negate    invert 1+ ; 
header -        : -         negate + ; 
header abs      : abs       dup 0< if negate then ; 
header 2*       : 2*        d# 1 lshift ; 
header 2/       : 2/        d# 1 rshift ; 
header here     : here      dp @ ;
header depth    : depth     depths h# f and ;

: /string
    dup >r - swap r> + swap
; 

header aligned
: aligned
    d# 3 + d# -4 and
; 

: d+                              ( augend . addend . -- sum . ) 
    rot + >r                      ( augend addend) 
    over +                        ( augend sum) 
    dup rot                       ( sum sum augend) 
    u< if                         ( sum) 
        r> 1+ 
    else 
        r> 
    then                          ( sum . ) 
; 

: d1+ d# 1. d+ ; 

: dnegate 
    invert swap invert swap 
    d1+ 
; 

: dabs ( d -- ud )
    dup 0< if dnegate then
; 

: s>d dup 0< ;
: m+
    s>d d+
;

: snap
    cr depth hex2 space
    begin
        depth
    while
        .
    repeat
    cr
    [char] # emit
    begin again
;

create scratch 0 ,

header um*
: um*  ( u1 u2 -- ud ) 
    scratch ! 
    d# 0. 
    d# 32 begin
        >r
        2dup d+ 
        rot dup 0< if 
            2* -rot 
            scratch @ d# 0 d+ 
        else 
            2* -rot 
        then 
        r> eol
    until
    rot drop 
; 
: *
    um* drop
;

header accept
: accept
    d# 30 emit
    drop dup
    begin
        key
        dup h# 0d xor
    while
        dup h# 0a = if
            drop
        else
            over c! 1+
        then
    repeat
    drop swap -
;

: 3rd   >r over r> swap ;
: 3dup  3rd 3rd 3rd ;

: sameword ( c-addr u wp -- c-addr u wp flag )
    2dup d# 2 + c@ = if
        3dup
        d# 3 + >r
        bounds
        begin
            2dupxor
        while
            dup c@ r@ c@ <> if
                2drop rdrop false exit
            then
            1+
            r> 1+ >r
        repeat
        2drop rdrop true
    else
        false
    then
;

\ lsb 0 means non-immediate, return -1
\     1 means immediate,     return  1
: isimmediate ( wp -- -1 | 1 )
    uw@ d# 1 and 2* 1-
;

: sfind
    ll uw@
    begin
        dup
    while
        sameword
        if 
            nip nip
            dup
            d# 2 +
            count +
            d# 1 + d# -2 and
            swap isimmediate
            exit
        then
        uw@
    repeat
;

: digit? ( c -- u f )
   dup h# 39 > h# 100 and +
   dup h# 140 > h# 107 and - h# 30 -
   dup base @ u<
;

: ud* ( ud1 u -- ud2 ) \ ud2 is the product of ud1 and u
    tuck * >r
    um* r> +
;

: >number ( ud1 c-addr1 u1 -- ud2 c-addr2 u2 )
    begin
        dup
    while
        over c@ digit?
        0= if drop exit then
        >r 2swap base @ ud*
        r> m+ 2swap
        d# 1 /string
    repeat
;

header fill
: fill ( c-addr u char -- ) ( 6.1.1540 ) 
  >r  bounds 
  begin
    2dupxor 
  while
    r@ over c! 1+ 
  repeat
  r> drop 2drop
; 

header erase
: erase
    d# 0 fill
;

header execute
: execute
    >r
;

header source
: source
    tib tib# @
;

\ From Forth200x - public domain

: isspace? ( c -- f )
    bl 1+ u< ;

: isnotspace? ( c -- f )
    isspace? 0= ;

: xt-skip   ( addr1 n1 xt -- addr2 n2 ) \ gforth
    \ skip all characters satisfying xt ( c -- f )
    >r
    BEGIN
    over c@ r@ execute
    over 0<> and
    WHILE
	d# 1 /string
    REPEAT
    r> drop ;

: parse-name ( "name" -- c-addr u )
    source >in @ /string
    ['] isspace? xt-skip over >r
    ['] isnotspace? xt-skip ( end-word restlen r: start-word )
    2dup d# 1 min + source drop - >in !
    drop r> tuck - ;

header !        :noname     !        ;
header +        :noname     +        ;
header xor      :noname     xor      ;
header and      :noname     and      ;
header or       :noname     or       ;
header invert   :noname     invert   ;
header =        :noname     =        ;
header <        :noname     <        ;
header u<       :noname     u<       ;
header swap     :noname     swap     ;
header dup      :noname     dup      ;
header drop     :noname     drop     ;
header over     :noname     over     ;
header nip      :noname     nip      ;
header @        :noname     @        ;
header io!      :noname     io!      ;
header rshift   :noname     rshift   ;
header lshift   :noname     lshift   ;
\ 
\ \ >r
\ \ r>
\ \ r@
\ \ exit
\ 

: xmain
    cr d# 1 ms cr
    d# 60 begin
        [char] - emit
    eol until
    begin key? while key drop repeat

    cr h# ffff hex8

    d# 0 d# 100 dump
    words cr cr

    begin again

    begin
        cr
        tib d# 30 accept >r
        d# 0. tib r> >number
        2drop hex4 space hex4
    again

    snap
;

: route
    r> + >r ;

\   (doubleAlso) ( c-addr u -- x 1 | x x 2 )
\               If the string is legal, leave a single or double cell number
\               and size of the number.

: isvoid ( caddr u -- ) \ any char remains, throw -13
    nip 0<>
    if [char] x emit snap then
;

: consume1 ( caddr u ch -- caddr' u' f )
    >r over c@ r> =
    over 0<> and
    dup>r d# 1 and /string r>
;

: (doubleAlso)
    h# 0. 2swap
    [char] - consume1 >r
    >number
    [char] . consume1 if
        isvoid              \ double number
        r> if dnegate then
        d# 2 exit
    then
                            \ single number
    isvoid drop
    r> if negate then
    d# 1
;

: doubleAlso
    (doubleAlso) drop
;


: dispatch
    route ;fallthru
    jmp execute                 \      -1      0       non-immediate
    jmp doubleAlso              \      0       0       number
    jmp execute                 \      1       0       immediate

\   jmp compile_comma           \      -1      2       non-immediate
\   jmp doubleAlso_comma        \      0       2       number
\   jmp execute                 \      1       2       immediate

: interpret
    begin
        parse-name dup
    while
        sfind 
        1+ 2* dispatch
    repeat
    2drop
;

: main
    2drop
    begin
        tib d# 80 accept
        tib# !
        \ h# 40 emit
        d# 0 >in !
        source dump
        \ cr parse-name sfind
        \ if
        \     execute
        \ then
        interpret
    again
;

meta
    $3f80 org 
target

: b.key
    begin
        d# 0 io@
        d# 4 and
    until
    d# 0 io@ d# 8 rshift
    d# 0 d# 2 io!
;

: b.32
    b.key
    b.key d# 8 lshift or
    b.key d# 16 lshift or
    b.key d# 24 lshift or
;

meta
    $3fc0 org 
target

: bootloader
    begin
        b.key d# 27 =
    until

    b.32 d# 0
    begin
        2dupxor
    while
        b.32 over !
        d# 4 +
    repeat
;

meta
    link @ t,
    link @ t' ll tw!
    there  t' dp tw!
target