summaryrefslogtreecommitdiff
path: root/larswm.m4
blob: 617cceb0554808cbac67dc0149b426d5834dee25 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
dnl $Id$

divert(-1)dnl

define(`cntr_app', `0')dnl
define(`cntr_dotile', `0')dnl
define(`cntr_dt', `0')dnl
define(`cntr_float', `0')dnl
define(`cntr_sticky', `0')dnl
define(`cntr_tool', `0')dnl

define(`INCR', `define(`$1', incr($1))')dnl

define(`PROP', `larswm.$1: $2')
define(`DTPROP', `larswm.$2.$3.$1: $4')
define(`DTPROPAS', `larswm.?.$2.$1: $3')
define(`DTPROPALL', `larswm.?.?.$1: $2')

define(`KEY', `larswm.$3_key: $1
larswm.$3_mod: $2')
define(`DTKEY', `larswm.$3_key.$4: $1
larswm.$3_mod: $2')

define(`APPM', `larswm.button$1.application: $2')
define(`APP', `larswm.application.cntr_app: $3
larswm.application_key.cntr_app: $1
larswm.application_mod.cntr_app: $2
INCR(`cntr_app')')

define(`DT', `larswm.dtclass.cntr_dt: $1
larswm.dtnum.cntr_dt: $2
INCR(`cntr_dt')')
define(`DOTILE', `larswm.dotileclass.cntr_dotile: $1
INCR(`cntr_dotile')')
define(`TOOL', `larswm.toolclass.cntr_tool: $1
INCR(`cntr_tool')')
define(`FLOAT', `larswm.floatclass.cntr_float: $1
INCR(`cntr_float')')
define(`STICKY', `larswm.stickyclass.cntr_sticky:$1
INCR(`cntr_sticky')')

divert(0)dnl