aboutsummaryrefslogtreecommitdiff
path: root/orrs/src/io.f
blob: 5299be85c6df57255a21e608e0c17990e6ed6723 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408

      SUBROUTINE READOS(FLIST,IFORM,
     &                  N,NMAX,ETA,U,S,
     &                  NRP,NWP,NHP,
     &                  RTL,WSL,HH , AR,AI,
     &                  NRX,NWX,NHX)
C----------------------------------------------------------------
C     Reads Orr-Sommerfeld data files in binary or ascii format.
C     Data is spatial amplification complex wavenumber
C           ar(Re,w,H)  ai(Re,w,H)
C     stored on a R,W,H grid
C           R = ln(Re)
C           W = ln(w) - 0.5 ln(Re)
C           H = H
C
C     Input
C       FLIST   name of text file containing file prefixes to be read
C       IFORM   -1=unknown
C                0=binary
C                1=ascii
C
C     Output
C       N(h)      number of points across BL,  i=1..N
C       NMAX      max dimension of N
C       ETA(i,h)  BL y coordinate
C       U(i,h)    velocity profile
C       S(i,h)    shear profile dU/deta
C       NRP(h)    number of RTL values, r=1..NRP
C       NWP(h)    number of WSL values, w=1..NWP
C       NHP       number of H   values, h=1..NHP
C       RTL(r,h)  R  values
C       WSL(w,h)  W  values
C       HH(h)     H  values
C       AR(r,w,h) real wavenumber
C       AI(r,w,h) imaginary wavenumber
C
C----------------------------------------------------------------
      CHARACTER*(*) FLIST
      DIMENSION N(NHX), NRP(NHX),NWP(NHX)
      DIMENSION ETA(NMAX,NHX), U(NMAX,NHX), S(NMAX,NHX)
      DIMENSION AR(NRX,NWX,NHX),AI(NRX,NWX,NHX)
      DIMENSION RTL(NRX,NHX), WSL(NWX,NHX), HH(NHX)
      CHARACTER*80 FNAME
C
      OPEN(10,FILE=FLIST,STATUS='OLD')
C
      WRITE(*,*) 'Reading...'
      DO 1000 IH=1, NHX
 5      READ(10,5000,END=1001) FNAME
 5000   FORMAT(A)
C
C------ skip comment line
        IF(INDEX('#!',FNAME(1:1)) .NE. 0) GO TO 5
C
C------ strip off leading blanks
 10     CONTINUE
        IF(FNAME(1:1).EQ.' ') THEN
         FNAME = FNAME(2:80)
         GO TO 10
        ENDIF
C
        CALL READOS1(FNAME,IFORM,
     &               N(IH),NMAX,ETA(1,IH),U(1,IH),S(1,IH),
     &               NRP(IH),NWP(IH),
     &               RTL(1,IH),WSL(1,IH),HH, AR(1,1,IH),AI(1,1,IH),
     &               NRX,NWX)
C
 1000 CONTINUE
      IH = NHX + 1
C
 1001 NHP = IH-1
      CLOSE(10)
C
      RETURN
      END ! READOS



      SUBROUTINE WRITOS(FLIST,IFORM,
     &                  N,NMAX,ETA,U,S,
     &                  NRP,NWP,NHP,
     &                  RTL,WSL,HH , AR,AI,
     &                  NRX,NWX,NHX)
C----------------------------------------------------------------
C     Writes Orr-Sommerfeld data files in binary or ascii format.
C     Data is spatial amplification complex wavenumber
C           ar(Re,w,H)  ai(Re,w,H)
C     stored on a R,W,H grid
C           R = ln(Re)
C           W = ln(w) - 0.5 ln(Re)
C           H = H
C
C     Input
C       FLIST   name of text file containing file prefixes to be read
C       IFORM   0=binary, ascii otherwise
C       N(h)      number of points across BL,  i=1..N
C       NMAX      max dimension of N
C       ETA(i,h)  BL y coordinate
C       U(i,h)    velocity profile
C       S(i,h)    shear profile dU/deta
C       NRP(h)    number of RTL values, r=1..NRP
C       NWP(h)    number of WSL values, w=1..NWP
C       NHP       number of H   values, h=1..NHP
C       RTL(r,h)  R  values
C       WSL(w,h)  W  values
C       HH(h)     H  values
C       AR(r,w,h) real wavenumber
C       AI(r,w,h) imaginary wavenumber
C
C     Output
C       written files
C
C----------------------------------------------------------------
C
      CHARACTER*(*) FLIST
      DIMENSION N(NHX), NRP(NHX),NWP(NHX)
      DIMENSION ETA(NMAX,NHX), U(NMAX,NHX), S(NMAX,NHX)
      DIMENSION AR(NRX,NWX,NHX),AI(NRX,NWX,NHX)
      DIMENSION RTL(NRX,NHX), WSL(NWX,NHX), HH(NHX)
      CHARACTER*80 FNAME
C
      OPEN(10,FILE=FLIST,STATUS='OLD')
C
      WRITE(*,*) 'Writing...'
      DO 1000 IH=1, NHX
 5      READ(10,5000,END=1001) FNAME
 5000   FORMAT(A)
C
C------ skip comment line
        IF(INDEX('#!',FNAME(1:1)) .NE. 0) GO TO 5
C
C------ strip off leading blanks
 10     CONTINUE
        IF(FNAME(1:1).EQ.' ') THEN
         FNAME = FNAME(2:80)
         GO TO 10
        ENDIF
C
        CALL WRITOS1(FNAME,IFORM,
     &               N(IH),NMAX,ETA(1,IH),U(1,IH),S(1,IH),
     &               NRP(IH),NWP(IH),
     &               RTL(1,IH),WSL(1,IH),HH, AR(1,1,IH),AI(1,1,IH),
     &               NRX,NWX)
C
 1000 CONTINUE
      IH = NHX + 1
C
 1001 NHP = IH-1
      CLOSE(10)
      CLOSE(9)
C
      RETURN
      END ! WRITOS



      SUBROUTINE READOS1(FNAME,IFORM,
     &                   N,NMAX,ETA,U,S,
     &                   NRP,NWP,
     &                   RTL,WSL,HH , AR, AI,
     &                   NRX,NWX)
C----------------------------------------------------------------
C     Reads Orr-Sommerfeld data file in binary or ascii format.
C     Data is spatial amplification complex wavenumber
C           ar(Re,w,H)  ai(Re,w,H)
C     stored on a R,W,H grid
C           R = ln(Re)
C           W = ln(w) - 0.5 ln(Re)
C           H = H
C
C     Input
C       FNAME   name of data file to be read
C       IFORM   -1=unknown
C                0=binary
C                1=ascii
C
C     Output
C       N       number of points across BL,  i=1..N
C       NMAX      max dimension of N
C       ETA(i)  BL y coordinate
C       U(i)    velocity profile
C       S(i)    shear profile dU/deta
C       NRP    number of RTL values, r=1..NRP
C       NWP    number of WSL values, w=1..NWP
C       RTL(r)  R  values
C       WSL(w)  W  values
C       HH      H  value
C       AR(r,w) real wavenumber
C       AI(r,w) imaginary wavenumber
C
C----------------------------------------------------------------
      CHARACTER*(*) FNAME
      REAL ETA(NMAX), U(NMAX), S(NMAX)
      REAL AR(NRX,NWX),AI(NRX,NWX)
      REAL RTL(NRX), WSL(NWX)
C
      IF(IFORM.LE.-1) THEN
C----- first assume it's an ascii file
       KFORM = 1
C
C----- try reading it as a binary
       OPEN(9,FILE=FNAME,STATUS='OLD',FORM='UNFORMATTED',ERR=1001)
       READ(9,ERR=11) NTEST, HTEST
C
       IF(NTEST.GE.1 .AND. NTEST.LE.NMAX) THEN
C------ point index within bounds... looks like it's binary
        KFORM = 0
       ENDIF
C
 11    CLOSE(9)
C
      ELSE
       KFORM = IFORM
C
      ENDIF
C
C
      K = INDEX(FNAME,' ') - 1
C
      IF(KFORM.EQ.0) THEN
C----- binary format
       FNAME = FNAME(1:K)
       WRITE(*,*) FNAME, '   binary'
C
       OPEN(9,FILE=FNAME,STATUS='OLD',FORM='UNFORMATTED',ERR=1001)
       READ(9,ERR=1001) N, HH
       READ(9) (ETA(I),I=1, N)
       READ(9) (U(I)  ,I=1, N)
       READ(9) (S(I)  ,I=1, N)
       READ(9) NRP, NWP
       READ(9) (RTL(IR),IR=1,NRP)
       READ(9) (WSL(IW),IW=1,NWP)
C
       DO IW=1, NWP
         READ(9,END=15) (AR(IR,IW),IR=1,NRP)
         READ(9,END=15) (AI(IR,IW),IR=1,NRP)
       ENDDO
       GO TO 30
C
 15    CONTINUE
       IWLAST = IW-1
       WRITE(*,*) 
     &     'Map incomplete.  Last complete frequency index:',IWLAST
C
      ELSE
C----- ascii format
       FNAME = FNAME(1:K)
       WRITE(*,*) FNAME, '   ascii'
C
       OPEN(9,FILE=FNAME,STATUS='OLD')
       READ(9,*) N, HH
       READ(9,*) (ETA(I),I=1, N)
       READ(9,*) (U(I)  ,I=1, N)
       READ(9,*) (S(I)  ,I=1, N)
       READ(9,*) NRP, NWP
       READ(9,*) (RTL(IR),IR=1,NRP)
       READ(9,*) (WSL(IW),IW=1,NWP)
C
       DO IW=1, NWP
         READ(9,*) (AR(IR,IW),IR=1,NRP)
         READ(9,*) (AI(IR,IW),IR=1,NRP)
       ENDDO
      ENDIF
C
 30   CONTINUE
      CLOSE(9)
      GEO = (ETA(3)-ETA(2)) / (ETA(2)-ETA(1))
      WRITE(*,2050) N, HH, ETA(N), GEO
 2050 FORMAT(' n =', I4,'   H =', F7.3,
     &                  '   Ye =', F7.3,
     &                  '   dYi+1/dYi =',F6.3 /)
      IFORM = 1
C
C
C---- re-order if needed to make RTL and WSL monotonically increasing
      IF(RTL(1) .GT. RTL(NRP)) THEN
       DO IR=1, NRP/2
         IRBACK = NRP-IR+1
C
         RTEMP = RTL(IR)
         RTL(IR) = RTL(IRBACK)
         RTL(IRBACK) = RTEMP
C
         DO IW=1, NWP
           ARTEMP = AR(IR,IW)
           AITEMP = AI(IR,IW)
           AR(IR,IW) = AR(IRBACK,IW)
           AI(IR,IW) = AI(IRBACK,IW)
           AR(IRBACK,IW) = ARTEMP
           AI(IRBACK,IW) = AITEMP
         ENDDO
       ENDDO
      ENDIF
C
      IF(WSL(1) .GT. WSL(NWP)) THEN
       DO IW=1, NWP/2
         IWBACK = NWP-IW+1
C
         WTEMP = WSL(IW)
         WSL(IW) = WSL(IWBACK)
         WSL(IWBACK) = WTEMP
C
         DO IR=1, NRP
           ARTEMP = AR(IR,IW)
           AITEMP = AI(IR,IW)
           AR(IR,IW) = AR(IR,IWBACK)
           AI(IR,IW) = AI(IR,IWBACK)
           AR(IR,IWBACK) = ARTEMP
           AI(IR,IWBACK) = AITEMP
         ENDDO
       ENDDO
C
      ENDIF
      RETURN
C
 1001 CONTINUE
      WRITE(*,*) 'File open error.'
      RETURN
      END ! READOS1


      SUBROUTINE WRITOS1(FNAME,IFORM,
     &                   N,NMAX,ETA,U,S,
     &                   NRP,NWP,
     &                   RTL,WSL,HH , AR, AI,
     &                   NRX,NWX)
C----------------------------------------------------------------
C     Writes Orr-Sommerfeld data file in binary or ascii format.
C     Data is spatial amplification complex wavenumber
C           ar(Re,w,H)  ai(Re,w,H)
C     stored on a R,W,H grid
C           R = ln(Re)
C           W = ln(w) - 0.5 ln(Re)
C           H = H
C
C     Input
C       FNAME    name of data file to be written
C       IFORM    0=binary, ascii otherwise
C       N        number of points across BL,  i=1..N
C       NMAX     max dimension of N
C       ETA(i)   BL y coordinate
C       U(i)     velocity profile
C       S(i)     shear profile dU/deta
C       NRP      number of RTL values, r=1..NRP
C       NWP      number of WSL values, w=1..NWP
C       RTL(r)   R  values
C       WSL(w)   W  values
C       HH       H  value
C       AR(r,w)  real wavenumber
C       AI(r,w)  imaginary wavenumber
C
C     Output
C       written file
C
C----------------------------------------------------------------
      CHARACTER*(*) FNAME
      REAL ETA(NMAX), U(NMAX), S(NMAX)
      REAL AR(NRX,NWX),AI(NRX,NWX)
      REAL RTL(NRX), WSL(NWX)
C
      K = INDEX(FNAME,' ') - 1
C
      IF(IFORM.EQ.0) THEN
       FNAME = FNAME(1:K) // '.bin'
       WRITE(*,*) FNAME
C
       OPEN(9,FILE=FNAME,STATUS='UNKNOWN',FORM='UNFORMATTED',ERR=1001)
       REWIND(9)
       WRITE(9,ERR=1001) N, HH
       WRITE(9) (ETA(I),I=1, N)
       WRITE(9) (U(I)  ,I=1, N)
       WRITE(9) (S(I)  ,I=1, N)
       WRITE(9) NRP, NWP
       WRITE(9) (RTL(IR),IR=1,NRP)
       WRITE(9) (WSL(IW),IW=1,NWP)
C
       DO IW=1, NWP
         WRITE(9) (AR(IR,IW),IR=1,NRP)
         WRITE(9) (AI(IR,IW),IR=1,NRP)
       ENDDO
C
      ELSE
       FNAME = FNAME(1:K)
       WRITE(*,*) FNAME
C
       OPEN(9,FILE=FNAME,STATUS='UNKNOWN')
       REWIND(9)
       WRITE(9,*) N, HH
       WRITE(9,*) (ETA(I),I=1, N)
       WRITE(9,*) (U(I)  ,I=1, N)
       WRITE(9,*) (S(I)  ,I=1, N)
       WRITE(9,*) NRP, NWP
       WRITE(9,*) (RTL(IR),IR=1,NRP)
       WRITE(9,*) (WSL(IW),IW=1,NWP)
C
       DO IW=1, NWP
         WRITE(9,*) (AR(IR,IW),IR=1,NRP)
         WRITE(9,*) (AI(IR,IW),IR=1,NRP)
       ENDDO
      ENDIF
C
      CLOSE(9)
      RETURN
C
 1001 CONTINUE
      WRITE(*,*) 'File open error.'
      RETURN
      END ! WRITOS1